Monthly Archives: January 2010

Metaplace creating Facebook games

I just saw this Craigslist posting for a new employee at Metaplace (where I worked for a few months):

http://sandiego.craigslist.org/csd/eng/1573745326.html

The title of the ad is: “Facebook game company seeking Flash developer”.

This is a great path for Metaplace. They have developed some wonderful game technology that is well suited for a Flash client embedded in a Facebook application.

Metaplace people are salt of the Earth and I wish them every success! They deserve it.

Perl function that returns info about a video (uses FFMPEG)

This program contains a Perl function I wrote to extract data about a given video.

It also shows how to parse information from program output and organize it usefully.

This has been used a few times in production systems.

If you use this, please drop a comment! It would be fun to know.

Share and enjoy!

#!/usr/bin/perl -w
# get_video_info.pl
# by Andrew Ault, www.andrewault.net
# Please drop me a note it you use this.

use strict;
use warnings;

use IPC::Open3;

# example
my $filename  = "yourvideoFilenameHere.mp4";
my %videoInfo = videoInfo($filename);
print "duration: " . $videoInfo{'duration'} . "\n";
print "durationsecs: " . $videoInfo{'durationsecs'} . "\n";
print "bitrate: " . $videoInfo{'bitrate'} . "\n";
print "vcodec: " . $videoInfo{'vcodec'} . "\n";
print "vformat: " . $videoInfo{'vformat'} . "\n";
print "acodec: " . $videoInfo{'acodec'} . "\n";
print "asamplerate: " . $videoInfo{'asamplerate'} . "\n";
print "achannels: " . $videoInfo{'achannels'} . "\n";

#
# returns media information in a hash
sub videoInfo {
	# ffmpeg command
	my $ffmpeg = '/usr/local/bin/ffmpeg';

	my %finfo = (
				  'duration'     => "00:00:00.00",
				  'durationsecs' => "0",
				  'bitrate'      => "0",
				  'vcodec'       => "",
				  'vformat'      => "",
				  'acodec'       => "",
				  'asamplerate'   => "0",
				  'achannels'       => "0", 
	);

	my $file = shift;

	# escaping characters
	$file =~ s/(\W)/\\$1/g;

	open3( "/dev/null", \*ERPH, "$ffmpeg -i $file" ) or die "can't run $ffmpeg\n";
	my @res = ;

	# parse ffmpeg output
	foreach (@res) {

		# duration
		if (m!Duration: ([0-9][0-9]:[0-9][0-9]:[0-9][0-9].[0-9][0-9])!) {
			$finfo{'duration'} = $1;
		}

		# bitrate
		if (m!bitrate: (\d*) kb/s!) {
			$finfo{'bitrate'} = $1;
		}

		# vcodec and vformat
		if (/Video: (\w*), (\w*),/) {
			$finfo{'vcodec'}  = $1;
			$finfo{'vformat'} = $2;
		}

        # Stream #0.1(und): Audio: aac, 48000 Hz, 1 channels, s16, 64 kb/s

		# acodec, samplerate, stereo and audiorate
		if (m!Audio: (\w*), (\d*) Hz, (\d*)!) {
			$finfo{'acodec'}     = $1;
			$finfo{'asamplerate'} = $2;
			$finfo{'achannels'}     = $3;
		}
	}

	my $tenths  = substr( $finfo{'duration'}, 9, 2 );
	my $seconds = substr( $finfo{'duration'}, 6, 2 );
	my $minutes = substr( $finfo{'duration'}, 3, 2 );
	my $hours   = substr( $finfo{'duration'}, 0, 2 );
	$finfo{'durationsecs'} = ( $tenths * .01 ) + $seconds + ( $minutes * 60 ) + ( $hours * 360 );

	return %finfo;
}

Create a test pattern video with Perl

I wanted a test pattern video to test a transcoding daemon I wrote for an iPhone application. I wanted to use the classic RCA test pattern image and a tone.

Simply edit the program header with the path to an image you want to use and the name of the output file you’d like to create.

You’ll need FFMPEG installed, of course.

You can change the audio tone if you’d like to.

If you use this script, please let me know.

Share and enjoy.

#!/usr/bin/perl -w
# create_test_pattern_video.pl
# by Andrew Ault, www.andrewault.net
#
# This produces a test pattern video from an image you supply with a tone that you specify.
#
use strict;
use warnings;

use File::Temp qw/ :mktemp tempdir /;
use File::Path;
use File::Spec;
use Audio::Wav;

# still image to create video from
my $fileImage = "/path/imageInputFilename.jpeg";

# output file - name of the file to output to
my $fileOutput = "/path/videoOutputFilename.mp4";

# video parameters
my $vFrameRate      = 25;
my $vBitRate        = "200k";
my $durationSeconds = 10;

# audio parameters - set up the tone to produce and use in the resulting video
my $hertz      = 400;
my $sampleRate = 44100;
my $sampleBits = 16;

#
my $dirTemp = tempdir("tmp-hax-XXXXXXXX");
$dirTemp = File::Spec->rel2abs($dirTemp) . "/";
my $numFrames = $vFrameRate * $durationSeconds;
my $cmd;
my $fileTmpAnimationVideo = $dirTemp . "animation.mp4";
my $fileTmpAudio          = $dirTemp . "sound.wav";

chdir $dirTemp;

# create a sequence of image files
print "creating image sequence\n";
for ( my $i = 1 ; $i <= $numFrames ; $i++ ) {
	my $seq = sprintf( "%08d", $i );
	$cmd = "cp $fileImage " . $seq . ".jpeg";
	print "$cmd\n";
	`$cmd`;
}

# create .mp4 from the image sequence
print "creating animation video\n";
$cmd = "ffmpeg -r $vFrameRate -b $vBitRate -i " . $dirTemp . "%08d.jpeg $fileTmpAnimationVideo";
print "$cmd\n";
`$cmd`;

# create the audio tone .wav
my $wav = Audio::Wav->new;
my $details = {
	'bits_sample' => $sampleBits,
	'sample_rate' => $sampleRate,
	'channels'    => 1,
};
my $write = $wav->write( $fileTmpAudio, $details );
&add_sine( $hertz, $durationSeconds );
$write->finish();

# combine the video and audio files to output
print "creating final output video file\n";
$cmd = "ffmpeg -y -i $fileTmpAnimationVideo -i $fileTmpAudio -acodec libfaac -ab 128k -ar 48000 $fileOutput";
print "$cmd\n";
`$cmd`;

# wrap it up
print "done\n";
rmtree($dirTemp);
exit(0);

sub add_sine {
	my $hz     = shift;
	my $length = shift;
	my $pi     = ( 22 / 7 ) * 2;
	$length *= $sampleRate;
	my $max_no = ( 2**$sampleBits ) / 2;
	for my $pos ( 0 .. $length ) {
		my $time = $pos / $sampleRate;
		$time *= $hz;
		my $val  = sin $pi * $time;
		my $samp = $val * $max_no;
		$write->write($samp);
	}
	return;
}

Top 10 Perl Sites

As is typical of my posts, this is another reference for my own use. When I can’t immediately remember something, I look here or on my private wiki. I hope you find this list useful.

perl.org

http://www.perl.org/

The mothership. Includes: Planet Perl : Perl History : Learn Perl : Online Perl Documentation

Home of the baddest Swiss Army Chainsaw there is.

CPAN

http://www.cpan.org/

The Comprehensive Perl Network. The reason I use Perl. Don not leave the womb with it.

Perl Monks

http://www.perlmonks.com/

Wide-ranging discussions of every possible Perl permutation.

Planet Perl

http://planet.perl.org/

Planet Perl is a regularly updated Perl blog with news from around the ‘net about Perl and Perl people. Definitely worth adding the RSS feed to Google Reader.

Perl.com

http://www.perl.com/

Infrequently updated, but still an interesting aggregate of Perl @ O’Reilly – the source of Perl paper artifacts.

Wiki Books Perl

http://en.wikibooks.org/wiki/Perl

A nice concentration of easily accessible Perl know how.

Perl 6

http://www.perl6.org/

The future of Perl…beyond 5.x

http://perl.net.au

http://perl.net.au

Great Perl resource.

The Perl Foundation

http://www.perlfoundation.org/

The Perl Foundation is dedicated to the advancement of the Perl programming language through open discussion, collaboration, design, and code.

Perl Design Patterns

http://perldesignpatterns.com/

Cargill’s quandary: “any design problem can be solved by adding an additional level of indirection, except for too many levels of indirection.”

My remote MySQL backup script in Perl – rtar_mysql.pl

Before you can use this script, you need to set up SSH so your local cron can access the remote servers without a password.

One thing to note about this script is that it automatically rotates the archived dump files; keeping a fie for the 1st of the week on a month, 1st of the month and 1st of the year.

see: Using Public/Private Key Pairs with SSH

Then, just modify the script for your database/servers (the block @ line 22).

This will create a series of files over time with daily/weekly/monthly MySQL dump backups.

#!/usr/bin/perl -w
# rtar_mysql.pl
#
# No arguments. The program is to be modified to include each database to be archived.
#
# Saves a tar of a remote mysql dump in a rotating file.
#
# This is used on Andrew's workstation to automatically grab a sql dump tar of each database daily.
#
use strict;
use warnings;

use DateTime;

my $fileError;
my $jobError  = 0;
my $jobErrors = "";
my $result;

# Specify a data block for each remote database to be archived.
my %dumpJobs = (
				 'db1' => {
							'remoteServer' => 'server_1',
							'database'     => 'database_name_1',
							'dbUser'       => 'database_username_1',
							'dbPassword'   => 'database_password_1',
							'dumpFilename' => 'server_1-database_name_1.dump.sql',
							'mysqlDumpCmd' => '/usr/bin/mysqldump',
							'tarCmd'       => '/bin/tar',
				 },
				 'db2' => {
							'remoteServer' => 'server_2',
							'database'     => 'database_name_2',
							'dbUser'       => 'database_username_1',
							'dbPassword'   => 'database_password_2',
							'dumpFilename' => 'server_2-database_name_2.dump.sql',
							'mysqlDumpCmd' => '/usr/bin/mysqldump',
							'tarCmd'       => '/bin/tar',
				 },
);

# Process each specified database dump/archive job.
for my $dumpJob ( sort keys %dumpJobs ) {
	$fileError = 0;
	my $tarballFilename = "$dumpJobs{$dumpJob}{'dumpFilename'}-" . tarDateSegment() . ".tgz";
	my $mysqlDumpCmd    = $dumpJobs{$dumpJob}{'mysqlDumpCmd'};
	my $tarCmd          = $dumpJobs{$dumpJob}{'tarCmd'};
	print "$dumpJob\n";

	my $dumpCommand = "ssh $dumpJobs{$dumpJob}{'remoteServer'} '$mysqlDumpCmd ";
	$dumpCommand .= "--user=$dumpJobs{$dumpJob}{'dbUser'} --password=$dumpJobs{$dumpJob}{'dbPassword'} ";
	$dumpCommand .= "$dumpJobs{$dumpJob}{'database'} > $dumpJobs{$dumpJob}{'dumpFilename'}'";
	print $dumpCommand . "\n";
	$result = system($dumpCommand );
	if ($result) { $fileError = 1; }

	if ( !$fileError ) {
		my $remoteMakeTarball = "ssh $dumpJobs{$dumpJob}{'remoteServer'} '$tarCmd ";
		$remoteMakeTarball .= "cvfz $tarballFilename $dumpJobs{$dumpJob}{'dumpFilename'}'";
		print $remoteMakeTarball . "\n";
		$result = system($remoteMakeTarball );
		if ($result) { $fileError = 1; }
	}

	if ( !$fileError ) {

		# using a more flexible naming scheme now
		my $downloadCommand = "scp $dumpJobs{$dumpJob}{'remoteServer'}:$tarballFilename .";
		print $downloadCommand . "\n";
		$result = system($downloadCommand );
		if ($result) { $fileError = 1; }
	}

	if ($fileError) {
		$jobError = 1;
		$jobErrors .= "$dumpJob ";
	}
}
if ($jobError) {
	warn "Errors were encountered: $jobErrors\n";
	exit(1);
}


sub tarDateSegment {
	my $dt = DateTime->now();

	my ( $sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst ) = localtime(time);
	$year += 1900;
	my $dateTime = sprintf "%4d-%02d-%02d %02d:%02d:%02d", $year, $mon + 1, $mday, $hour, $min, $sec;
	my $date     = sprintf "%4d-%02d-%02d",                $year, $mon + 1, $mday;
	my @weekdays = qw( sun mon tue wed thu fri sat );
	my $weekday  = $weekdays[$wday];
	my @months   = qw( jan feb mar apr may jun jul aug sep oct nov dec );
	my $month    = $months[$mon];

	my $weekOfMonth = $dt->week_of_month;

	my $dateTar = "";

	# if the first day of the year, set $dateTar like: 2009-1st
	if ( $yday == 1 ) {
		$dateTar = "$year-1st";
	}

	# if the first day of the month, set $dateTar like: feb-1st
	elsif ( $mday == 1 ) {
		$dateTar = "$month-1st";
	}

	# if the first day of the week, set $dateTar like: mon-1
	# where the number is the week of the month number
	elsif ( $wday == 1 ) {
		$dateTar = "$weekday-$weekOfMonth";
	}

	# otherwise, set the $dateTar like: mon
	else {
		$dateTar = "$weekday";
	}

	# $sec      seconds          54
	# $min      monutes          37
	# $hour     hour             11
	# $mon      month            4
	# $year     year             2009
	# $wday     weekday          3
	# $yday     day of the year  146
	# $isdst    is DST           1
	# $weekday  day of the week  wed
	# $month    month            may
	# $dateTime date and time    2009-05-27 11:37:54
	# $date     date             2009-05-27
	return $dateTar;
}

=head1 NAME

rtar_mysql.pl - Andrew's remote MySQL archive program.

=head1 SYNOPSIS

    use: rtar_mysql.pl

=head1 DESCRIPTION

This is a program I wrote to SSH/dump/tar/download/rotate archives of MySQL databases.

=over

=back

=head1 LICENSE

None.

=head1 AUTHOR

Andrew Ault 

=cut

Perl program for makeiPhoneRefMovie

This creates the small .mov (or whatnot) redirect files that Apple’s makeiPhoneRefMovie generates. This is simply a driver to creat those files with makeiPhoneRefMovie.

#!/usr/bin/perl -w
#
# gen_mwn_iphone_mov_redirect_files.pl
#
# This makes the special iPhone .mov rediect files (~ 300 bytes) that the iPhone
# uses to redirect to the appropriate actual movie file.
#
# To use this utility:
#
# Make sure that the program makeiPhoneRefMovie is in your $PATH with:
#
#  which makeiPhoneRefMovie
#
# Then, let fly!
#
# ./gen_mwn_iphone_mov_redirect_files.pl
#
# Then, FTP the .mov files that are created up to the CDN.
#

use strict;
use File::Basename;
use Net::FTP;
use DBI;
use Cwd;

# Where to output files
my $dirOutput = "./iphone-ref-movs/";

my $dirBase = getcwd;

# Working directories
my %workingDirs = ( dirOutput => $dirBase . "/iphone-ref-movs/", );

# Prepend url strings
my $url3gp = "http://low_bandbidth_url_goes_here/";
my $urlM4v = "http://high_bandbidth_url_goes_here/";

# MySQL connection data
my $dbHost     = "db_hostname_here";
my $dbDatabase = "db_databasename_here";
my $mysqlDsn   = "DBI:mysql:$dbDatabase;host=$dbHost";
my $dbUsername = "db_username_here";
my $dbPassword = "db_password_here";

# Create working directories, if they do not already exist.
while ( my ( $key, $value ) = each(%workingDirs) ) {
	if ( !-d $value ) { mkdir $value or die $!; }
	print $key . ": " . $value . "\n";
}

# Connect to MySQL database
my $dbh = DBI->connect( $mysqlDsn, $dbUsername, $dbPassword )
  or die "Cannot connect to database $dbHost: $@";

# Get a list of @songFilenames from the database
my $sqlQuery = "SELECT filename FROM videos WHERE filename != ''";
my $sth      = $dbh->prepare($sqlQuery);
$sth->execute();
my @songFilenames;
while ( my ($songFilename) = $sth->fetchrow_array() ) {
	push( @songFilenames, $songFilename );
}
$dbh->disconnect();
my $numSongIds = @songFilenames;

# Create the mov redirect files
foreach my $songFilename (@songFilenames) {
	my $dirOutput = $workingDirs{dirOutput};

	my $url3gp = $url3gp . $songFilename . ".3gp";
	my $urlM4v = $urlM4v . $songFilename . ".m4v";
	my $filenameMov = $dirOutput . $songFilename . ".mov";

	my $cmd       = "makeiPhoneRefMovie $url3gp $urlM4v $urlM4v $filenameMov";
	system($cmd);
}

Perl script to compare 2 directories

This is a quick Perl script that I wrote to solve a particular problem; I needed to check two directories, one of original files and one of transcoded files, to see which files were missing from the second directory. The files in the second directory have different filename extensions, so the utility needs to take this into consideration.

So, this utility checks the two directories, ignoring file extensions and shows the missing files in each directory.

#!/usr/bin/perl -w
# dircomp.pl
#
# Compares filenames in two directories, without regard to 3-letter file extension.
# Displays list(s) of the differences.
#
# This was written to show missing transcoded files in one dir compared to another.
#
use strict;
use List::Compare;
use File::Basename;

my $resultsFound = 0;
my $fileName;
my $filePath;
my $fileExt;

if ( $#ARGV < 1 ) {
    &usage;
}

my $dir1 = $ARGV[0];
my $dir2 = $ARGV[1];

print "\ndircomp directory comparison\n";
print "\ncomparing:\t$dir1\nwith:\t\t$dir2";

opendir( DIR1h, $dir1 )
  || die("cannot open directory: $dir1");
opendir( DIR2h, $dir2 )
  || die("cannot open directory: $dir2");

my @files1 = readdir(DIR1h);
my @files2 = readdir(DIR2h);


# Remove filename extensions for each list.
foreach my $item (@files1) {
    my ( $fileName, $filePath, $fileExt ) = fileparse($item, qr/\.[^.]*/);
    $item = $fileName;
}

foreach my $item (@files2) {
    my ( $fileName, $filePath, $fileExt ) = fileparse($item, qr/\.[^.]*/);
    $item = $fileName;
}

my $lc = List::Compare->new( \@files1, \@files2 );

my @onlyInDir1 = $lc->get_Lonly;
my @onlyInDir2 = $lc->get_Ronly;

if ( @onlyInDir1 > 0 ) {
    $resultsFound = 1;
    print "\n\nonly in $dir1:\n\n";
    for my $entry (@onlyInDir1) {
        print "$entry\n";
    }
}

if ( @onlyInDir2 > 0 ) {
    $resultsFound = 1;
    print "\n\nonly in $dir2:\n\n";
    for my $entry (@onlyInDir2) {
        print "$entry\n";
    }
}

if ( !$resultsFound ) {
    print "\n\nboth directories are identical.\n";
}

sub usage
{
    print "usage: dircomp.pl dir1 dir2\n";
    exit(0);
}

My file rotating MySQL database dumper

This is a script to be run from a daily cron that created a series of sanely named SQL dump files: weekly, monthly, etc.

Always have that backup ready!

#!/usr/bin/perl -w
#
# No arguments. The program is to be modified to include each database to be archived.
#
#
use strict;
use warnings;

use DateTime;

my $numRotations = 6;    # base 0,  so 6 = 7 rotations (.0 through .6)... plus the new file, so 8 total files
my $fileError;
my $jobError  = 0;
my $jobErrors = "";
my $result;

# Specify a data block for each remote database to be archived.
my %dumpJobs = (
				 'db1' => {
							'database'     => 'db1',
							'dbUser'       => 'db1username',
							'dbPassword'   => 'db1password',
							'dumpFilename' => 'db1.dump.sql',
							'mysqlDumpCmd' => '/usr/bin/mysqldump',
							'tarCmd'       => '/usr/bin/tar',
				 },
);

# Process each specified database dump/archive job.
for my $dumpJob ( sort keys %dumpJobs ) {
	$fileError = 0;
	my $tarballFilename = "$dumpJobs{$dumpJob}{'dumpFilename'}-" . tarDateSegment() . ".tgz";
	my $mysqlDumpCmd    = $dumpJobs{$dumpJob}{'mysqlDumpCmd'};
	my $tarCmd          = $dumpJobs{$dumpJob}{'tarCmd'};
	print "$dumpJob\n";

	my $dumpCommand = "$mysqlDumpCmd ";
	$dumpCommand .= "--user=$dumpJobs{$dumpJob}{'dbUser'} --password=$dumpJobs{$dumpJob}{'dbPassword'} ";
	$dumpCommand .= "$dumpJobs{$dumpJob}{'database'} > $dumpJobs{$dumpJob}{'dumpFilename'}";
	print $dumpCommand . "\n";
	$result = system($dumpCommand );
	if ($result) { $fileError = 1; }

	# create tarball
	if ( !$fileError ) {
		my $makeTarball = "$tarCmd ";
		$makeTarball .= "cvfz $tarballFilename $dumpJobs{$dumpJob}{'dumpFilename'}";
		print $makeTarball . "\n";
		$result = system($makeTarball );
		if ($result) { $fileError = 1; }
	}

	if ($fileError) {
		$jobError = 1;
		$jobErrors .= "$dumpJob ";
	}
}
if ($jobError) {
	warn "Errors were encountered: $jobErrors\n";
	exit(1);
}

# This rotates a series of files Unix log rotation style.
# CURRENTLY UNUSED - KEPT BECAUSE IT IS SO HANDY
#
# Run this with the name of the file to rotate and the max # of rotations, just before you
# create the newest iteration of the file. This will rename the older versions by appending
# ".0" though the number of rotations specified. (So it will actually keep one more than specified,
# including ".0".)
sub rotateFile {
	my ( $filename, $numRotations ) = @_;

	# if the highest exists, delete it
	if ( -f $filename . ".$numRotations" ) { unlink $filename . ".$numRotations"; }

	#
	for ( my $count = $numRotations ; $count >= 1 ; $count-- ) {
		my $fromFilename = $filename . "." . ( $count - 1 );
		my $toFilename = $filename . "." . $count;
		if ( -f $fromFilename ) {
			rename $fromFilename, $toFilename;
		}
	}
	if ( -f $filename ) {
		rename $filename, $filename . ".0";
	}
}

sub tarDateSegment {
	my $dt = DateTime->now();

	my ( $sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst ) = localtime(time);
	$year += 1900;
	my $dateTime = sprintf "%4d-%02d-%02d %02d:%02d:%02d", $year, $mon + 1, $mday, $hour, $min, $sec;
	my $date     = sprintf "%4d-%02d-%02d",                $year, $mon + 1, $mday;
	my @weekdays = qw( sun mon tue wed thu fri sat );
	my $weekday  = $weekdays[$wday];
	my @months   = qw( jan feb mar apr may jun jul aug sep oct nov dec );
	my $month    = $months[$mon];

	my $weekOfMonth = $dt->week_of_month;

	my $dateTar = "";

	# if the first day of the year, set $dateTar like: 2009-1st
	if ( $yday == 1 ) {
		$dateTar = "$year-1st";
	}

	# if the first day of the month, set $dateTar like: feb-1st
	elsif ( $mday == 1 ) {
		$dateTar = "$month-1st";
	}

	# if the first day of the week, set $dateTar like: mon-1
	# where the number is the week of the month number
	elsif ( $wday == 1 ) {
		$dateTar = "$weekday-$weekOfMonth";
	}

	# otherwise, set the $dateTar like: mon
	else {
		$dateTar = "$weekday";
	}

	# $sec      seconds          54
	# $min      monutes          37
	# $hour     hour             11
	# $mon      month            4
	# $year     year             2009
	# $wday     weekday          3
	# $yday     day of the year  146
	# $isdst    is DST           1
	# $weekday  day of the week  wed
	# $month    month            may
	# $dateTime date and time    2009-05-27 11:37:54
	# $date     date             2009-05-27
	return $dateTar;
}

=head1 NAME

rtar_mysql.pl - Andrew's remote MySQL archive program.

=head1 SYNOPSIS

    use: rtar_mysql.pl

=head1 DESCRIPTION

This is a program I wrote to SSH/dump/tar/download/rotate archives of MySQL databases.

=over

=back

=head1 LICENSE

None.

=head1 AUTHOR

Andrew Ault 

=cut

Komodo IDE macro to process current file with PHP Beautifier

I use Komodo IDE for dynamic languages. I like it because it works extremely well and you get a license to use it on whatever machine you happen to be sitting at. Also it works well in Ubuntu and Mac OS/X, both of which I use constantly.

Here’s a macro I use in Komodo to make the file I am currently editing instantly pretty:

var ke = komodo.editor
if (komodo.view.scintilla) { komodo.view.scintilla.focus(); }
var currentPos = komodo.editor.currentPos;
 
try {
    var tidycmd = "/usr/bin/php_beautifier -t1 -l 'Pear() ArrayNested IndentStyles() NewLines'"
    komodo.doCommand('cmd_save');
    ke.beginUndoAction();
    komodo.doCommand('cmd_selectAll');
    Run_RunEncodedCommand(window, tidycmd + " {'insertOutput': True, 'operateOnSelection': True}");
    ke.gotoPos(currentPos);
    komodo.doCommand('cmd_cleanLineEndings');
} catch (e) {
    alert(e);
} finally {
    ke.endUndoAction();
}